The Idolm@ster @utf audio files

[Cornal_Ec]

Hi, I've tried to extract some audio files from this game, but without luck.
The files header is @utf, but seems those contain a AFS2 file inside of it.

Here's some samples:

Assets.rar

Regards.

[ponaromixxx]

Code: Select all

## Based On
# CRI Audio @UTF (script 0.1.3)
#   thanks to Taylor&Lion for the alignment field
# script for QuickBMS http://quickbms.aluigi.org

quickbmsver "0.7.3"

idstring "@UTF"

get FILESIZE asize 0

goto 0 0
findloc OFFSET_HEADER string "StreamAwbAfs2Header" 0 ""
if OFFSET_HEADER == ""
    cleanexit
endif

goto OFFSET_HEADER 0
findloc OFFSET_FILENAME string "CueIndex" 0 ""
if OFFSET_FILENAME == ""
    cleanexit
endif

goto OFFSET_FILENAME 0

set FILENAME_COUNT 0
get DUMMY string
for
    get FILENAME string

    if FILENAME != ""
        putarray 0 FILENAME_COUNT FILENAME
        math FILENAME_COUNT += 1
    else
        break
    endif
next

findloc OFFSET_MAIN string "AFS2" 0 ""
if OFFSET_MAIN == ""
    cleanexit
endif

goto OFFSET_MAIN 0

get HEADER long
get DUMMY long
get FILES long
get MYALIGN long
for i = 0 < FILES
    get ALIGN short
    putarray 1 i ALIGN
next i

    callfunction GET_OFFSET 1
math OFFSET = VALUE
for i = 0 < FILES
    callfunction GET_OFFSET 1
    math NEXT_OFFSET = VALUE

    getarray FILENAME 0 i
    if MYALIGN != 0
        math ALIGN = MYALIGN
    else
        getarray ALIGN 1 i
    endif

    math OFFSET x= ALIGN
    math OFFSET_FILE = OFFSET_MAIN
    math OFFSET_FILE += OFFSET
    math SIZE = NEXT_OFFSET
    math SIZE -= OFFSET
    math OFFSET = NEXT_OFFSET
    string FILENAME += ".hca"

    log FILENAME OFFSET_FILE SIZE
next i


startfunction GET_OFFSET
    if DUMMY & 0x200
        get VALUE short
    else
        get VALUE long
    endif
endfunction

HCA Decoder v2.zip

[Cornal_Ec]

Thanks a lot @ponaromixxx, but the decoder doesn't work well, the audio runs so fast or maybe I'm doing something wrong.

[ponaromixxx]

Thanks a lot @ponaromixxx, but the decoder doesn't work well, the audio runs so fast or maybe I'm doing something wrong.

Replaced decoder!

HCA Decoder v2.zip

[Cornal_Ec]

Good work, Thank You So Much!!!!!